Creating bootable Porteus 5.0rc3 USB in Windows 10

Technical issues/questions of an intermediate or advanced nature.
Post Reply
User avatar
Ed_P
Contributor
Contributor
Posts: 6360
Joined: 06 Feb 2013, 22:12
Distribution: Cinnamon 4.0 & 5.0rc3 ISOs
Location: Western NY, USA

Creating bootable Porteus 5.0rc3 USB in Windows 10

Post#1 by Ed_P » 01 Aug 2021, 17:15

This worked for me and booted on my Windows 10 UEFI system.

USB50.cmd

Code: Select all

@echo off&title Install Porteus

:: ## Partition & format the USB drive with a msdos Partition table.  ##
:: ## > diskpart          * Run Command Prompt with Admin Rights.     ##
:: ## > list disk                                                                                        ##
:: ## >....                                                                                                 ##
:: ## > select disk 1   * Note: disk nbr is the nbr of the USB disk       ##
:: ## > clean                                                                                           ##
:: ## > exit                                                                                              ##

::  User customize settings.  ISOdrv can be set when running if wrong. 
set ISO=D:\ISOs\Porteus-CINNAMON-v5.0rc3-x86_64.iso           
set ISOdrv=H:
set USBdrv=G:

echo Mounting %ISO%
powershell Mount-DiskImage -ImagePath "%ISO%"

if not exist %ISOdrv%\USB_INSTALLATION.txt (
   set /p ISOdrv=Enter ISO's mount drive or q to quit: ) 
if /I "%ISOdrv%" == "q" exit
if exist %ISOdrv%\USB_INSTALLATION.txt (
   echo "ISO drive: %ISOdrv%" 
) else ( 
   echo "Invalid ISO mount drive"
   pause > nul
   exit)

vol %USBdrv%  > nul 
if %errorLevel% == 0 (
   echo "USB drive: %USBdrv%" 
) else ( 
   echo "Invalid USB drive"
   pause > nul
   exit)

echo.
echo Copying files from %ISOdrv%\ to %USBdrv%\ 
xcopy %ISOdrv%\* %USBdrv%\ /y /s /c

if %errorLevel% == 0 (
   dir %USBdrv%\ 
) else ( 
   echo "Xcopy failed!"
   pause > nul
   exit)

echo.
echo Installing Porteus to the %USBdrv% drive
cd /d %USBdrv%\boot
Porteus-installer-for-Windows.exe
label %USBdrv% Porteus

echo Dismounting %ISO%
powershell Dismount-DiskImage -ImagePath "%ISO%"

echo Done
pause > nul
exit
But on my Windows 10 BIOS machine I get:

Code: Select all

SYSLINX 4.06 EDD 2012-10-23 Copyright (C) 1994-2012 H. Peter Anvin et al 
vesamenu.c32: not a COM32R image
boot:
loop. Trying to break out gives:

Code: Select all

Could not find kernel image: init
Ed

User avatar
ncmprhnsbl
DEV Team
DEV Team
Posts: 3156
Joined: 20 Mar 2012, 03:42
Distribution: 5.0-current-64bit
Location: australia
Contact:

Creating bootable Porteus 5.0rc3 USB in Windows 10

Post#2 by ncmprhnsbl » 01 Aug 2021, 23:01

the syslinux installers have no effect on uefi booting.
try these linked in this post ..(unzip them first)
Unable to boot Porteus 5.0 rc3 in Legacy mode (Post by ncmprhnsbl #83479)
Forum Rules : https://forum.porteus.org/viewtopic.php?f=35&t=44

User avatar
Ed_P
Contributor
Contributor
Posts: 6360
Joined: 06 Feb 2013, 22:12
Distribution: Cinnamon 4.0 & 5.0rc3 ISOs
Location: Western NY, USA

Creating bootable Porteus 5.0rc3 USB in Windows 10

Post#3 by Ed_P » 01 Aug 2021, 23:42

Thank you ncmp. I remembered reading about the c32 error but couldn't find it until I googled for it. Will test it more later.
Ed

User avatar
Ed_P
Contributor
Contributor
Posts: 6360
Joined: 06 Feb 2013, 22:12
Distribution: Cinnamon 4.0 & 5.0rc3 ISOs
Location: Western NY, USA

Creating bootable Porteus 5.0rc3 USB in Windows 10

Post#4 by Ed_P » 04 Aug 2021, 16:37

BTW On the BIOS 64bit system when the vesamenu.c32 error occurs if I hit the tab key then enter "text" to the boot option Porteus boots to a terminal screen where I login as root then enter "init 4" and Porteus boots to the normal GUI desktop. :)
Ed

User avatar
Ed_P
Contributor
Contributor
Posts: 6360
Joined: 06 Feb 2013, 22:12
Distribution: Cinnamon 4.0 & 5.0rc3 ISOs
Location: Western NY, USA

Creating bootable Porteus 5.0rc3 USB in Windows 10

Post#5 by Ed_P » 12 Aug 2021, 21:16

If someone is using a used USB drive or wants to rerun the USB install this version removes the old files/folder before adding Porteus to it.

USB50.cmd

Code: Select all

@echo off&title Install Porteus

:: ## Partition & format the USB drive with a msdos Partition table.  ##
:: ## > diskpart          * Run Command Prompt with Admin Rights.     ##
:: ## > list disk                                                                                        ##
:: ## >....                                                                                                 ##
:: ## > select disk 1   * Note: disk nbr is the nbr of the USB disk       ##
:: ## > clean                                                                                           ##
:: ## > exit                                                                                              ##

::  User customize settings.  ISOdrv can be set when running if wrong.
::set ISO=D:\ISOs\Porteus-CINNAMON-v5.0rc3-x86_64.iso
set ISO=D:\ISOs\Porteus-CINNAMON-v5.0rc3-i586.iso
set ISOdrv=H:
set USBdrv=G:


:: Check for Run as Admin
net sessions >nul 2>&1
if %errorLevel% == 0 (
   echo Running as Admin. 
   echo.    
 ) else (
    echo.
    echo  Deleting folders requires running as Admin.
    pause > nul
    exit
 )
echo Rerun
rmdir %USBdrv%\ /s
dir %USBdrv%\ > nul 2>&1
if %errorLevel% == 0 (
   echo "%USBdrv% not empty" 
   pause > nul
   exit
) else ( 
   echo "%USBdrv% is empty"
   echo.
)

echo Mounting %ISO%
powershell Mount-DiskImage -ImagePath "%ISO%"
::powershell Dismount-DiskImage -ImagePath "D:\ISOs\Porteus-CINNAMON-v5.0rc3-x86_64.iso"

if not exist %ISOdrv%\USB_INSTALLATION.txt (
   set /p ISOdrv=Enter ISO's mount drive or Q to quit: ) 
if /I "%ISOdrv%" == "q" exit
if exist %ISOdrv%\USB_INSTALLATION.txt (
   echo "ISO drive: %ISOdrv%" 
) else ( 
   echo "Invalid ISO mount drive"
   pause > nul
   exit)

vol %USBdrv%  > nul 
if %errorLevel% == 0 (
   echo "USB drive: %USBdrv%" 
) else ( 
   echo "Invalid USB drive"
   pause > nul
   exit)

echo.
echo Copying files from %ISOdrv%\ to %USBdrv%\ 
xcopy %ISOdrv%\* %USBdrv%\ /y /s /c

if %errorLevel% == 0 (
   dir %USBdrv%\ 
) else ( 
   echo "Xcopy failed!"
   pause > nul 
   exit)

echo.
echo Installing Porteus to the %USBdrv% drive

cd /d %USBdrv%\boot
Porteus-installer-for-Windows.exe
label %USBdrv% Porteus

echo Dismounting %ISO%
powershell Dismount-DiskImage -ImagePath "%ISO%"

echo Done
pause > nul
exit
Ed

Post Reply